Двусторонняя печать

Комментарии

• Daedra

  February 2015 отредактировано 21:59

  Можно.
  Проверяем, возможна ли дуплексная печать у текущего принтера:
  

  function IsDuplexPrintSupported: Boolean;
  var
    Device, Driver, Port: array[0..255] of Char;
    hDevMode: THandle;
  begin
    Printer.GetPrinter(Device, Driver, Port, hDevmode);
    Result := WinSpool.DeviceCapabilities(Device, Port, DC_DUPLEX, nil, nil) <> 0;
  end;
  

  
  Затем устанавливаем дуплексной печати вертикальный либо горизонтальный в зависимости от ориентации страницы.
  Если портретная ориентация, значит вертикальный дуплексный режим:

  procedure SetVerticalDuplexPrintMode;
  begin
    SetDuplexPrintMode(DMDUP_VERTICAL)
  end;
  

  
  Если альбомная ориентация, горизонтальный дуплексный режим:

  procedure SetHorizontalDuplexPrintMode;
  begin
    SetDuplexPrintMode(DMDUP_HORIZONTAL)
  end;
  

  
  
  Вернуть одностороннюю печать:

  procedure SetSimplexDuplexPrintMode;
  begin
    SetDuplexPrintMode(DMDUP_SIMPLEX)
  end;
  

  procedure SetDuplexPrintMode(DuplexMode: SmallInt);
  var
    Device, Driver, Port: array[0..80] of Char;
    DevMode: THandle;
    pDevmode: PDeviceMode;
  begin
    // Get printer device mode handle.
    Printer.GetPrinter(Device, Driver, Port, DevMode);
    if Devmode <> 0 then
    begin
      // lock it to get pointer to DEVMODE record
      pDevMode := GlobalLock(Devmode);
      if pDevmode <> nil then
      try
        with pDevmode^ do
        begin
          dmDuplex := DuplexMode;
          dmFields := dmFields or DM_DUPLEX;
        end;
      finally
        // unlock devmode handle.
        GlobalUnlock(Devmode);
      end;
    end;
  end;
  

  
  Узнать текущий дуплексный режим:

  function GetDuplexPrintMode: Smallint;
  var
    Device, Driver, Port: array[0..80] of Char;
    DevMode: THandle;
    pDevmode: PDeviceMode;
  begin
    Result := DMDUP_SIMPLEX; //no duplex default
    Printer.GetPrinter(Device, Driver, Port, DevMode);
    if Devmode <> 0 then
    begin
      pDevMode := GlobalLock(Devmode);
      if pDevmode <> nil then
      try
        with pDevmode^ do
          Result := dmDuplex;
      finally
        GlobalUnlock(Devmode);
      end;
    end;
  end;